mail

hosts/hermes/default.nix

@@ -0,0 +1,57 @@
+{
+  inputs,
+  config,
+  pkgs,
+  ...
+}:
+let
+  userName = "love";
+  fullName = "Love";
+  hostName = "Hermes";
+  homeDir = "/home/${userName}";
+  installDisk = "/dev/disk/by-id/scsi-0QEMU_QEMU_HARDDISK_115386992";
+in
+{
+  _module.args = {
+    inherit
+      fullName
+      homeDir
+      hostName
+      installDisk
+      userName
+      ;
+  };
+
+  imports = [
+    inputs.mailserver.nixosModules.default
+    ./hardware-configuration.nix
+    ./disko.nix
+    ./mail.nix
+    ./roundcube.nix
+    ../../modules/base.nix
+    ../../modules/zfs-root.nix
+    ../../modules/desktop-hyprland.nix
+    ../../modules/bin-bash-wrapper.nix
+  ];
+
+  my.binBashWrapper.enable = true;
+
+  networking.hostName = hostName;
+  networking.hostId = "8d49a097f2";
+
+  users.mutableUsers = true;
+  users.users.${userName} = {
+    isNormalUser = true;
+    description = fullName;
+    extraGroups = [ "wheel" ];
+    shell = pkgs.bash;
+  };
+
+  zramSwap = {
+    enable = true;
+    memoryPercent = 75;
+    algorithm = "zstd";
+  };
+
+  system.stateVersion = "25.05";
+}

hosts/hermes/disko.nix

@@ -0,0 +1,118 @@
+{ installDisk, ... }:
+{
+  disko.devices = {
+    disk.main = {
+      type = "disk";
+      device = installDisk;
+      content = {
+        type = "gpt";
+        partitions = {
+          ESP = {
+            label = "EFI";
+            size = "512MiB";
+            type = "EF00";
+            content = {
+              type = "filesystem";
+              format = "vfat";
+              mountpoint = "/boot";
+              mountOptions = [ "umask=0077" ];
+            };
+          };
+
+          luks = {
+            label = "cryptroot";
+            size = "100%";
+            content = {
+              type = "luks";
+              name = "cryptroot";
+              settings = {
+                allowDiscards = true;
+              };
+              content = {
+                type = "zfs";
+                pool = "rpool";
+              };
+            };
+          };
+
+        };
+      };
+    };
+
+    zpool.rpool = {
+      type = "zpool";
+
+      options = {
+        ashift = "12";
+        autotrim = "on";
+      };
+
+      rootFsOptions = {
+        acltype = "posixacl";
+        atime = "off";
+        compression = "zstd";
+        dnodesize = "auto";
+        mountpoint = "none";
+        normalization = "formD";
+        xattr = "sa";
+      };
+
+      datasets = {
+        root = {
+          type = "zfs_fs";
+          options.mountpoint = "none";
+        };
+
+        "root/nixos" = {
+          type = "zfs_fs";
+          mountpoint = "/";
+          options = {
+            canmount = "noauto";
+            mountpoint = "legacy";
+          };
+          postCreateHook = "zfs snapshot rpool/root/nixos@blank";
+        };
+
+        home = {
+          type = "zfs_fs";
+          mountpoint = "/home";
+          options.mountpoint = "legacy";
+        };
+
+        nix = {
+          type = "zfs_fs";
+          mountpoint = "/nix";
+          options.mountpoint = "legacy";
+        };
+
+        persist = {
+          type = "zfs_fs";
+          mountpoint = "/persist";
+          options.mountpoint = "legacy";
+        };
+
+        var = {
+          type = "zfs_fs";
+          options.mountpoint = "none";
+        };
+
+        "var/log" = {
+          type = "zfs_fs";
+          mountpoint = "/var/log";
+          options.mountpoint = "legacy";
+        };
+
+        "var/lib" = {
+          type = "zfs_fs";
+          mountpoint = "/var/lib";
+          options.mountpoint = "legacy";
+        };
+
+        reserved = {
+          type = "zfs_volume";
+          size = "1G";
+        };
+      };
+    };
+  };
+}

hosts/hermes/mail-password-hash/love@billenius.com

@@ -0,0 +1 @@
+$y$j9T$JkGgFVlME8sM9iB7piz95.$oRbUxpuVQBXUlTjDREJq2cNdUGR65ADUbZ7cbAje9/A

hosts/hermes/mail.nix

@@ -0,0 +1,24 @@
+{ config, ... }:
+{
+  security.acme.acceptTerms = true;
+  networking.firewall.allowedTCPPorts = [ 80 ];
+  services.nginx.virtualHosts.${config.mailserver.fqdn}.enableACME = true;
+
+  mailserver = {
+    enable = true;
+    stateVersion = 4;
+    fqdn = "mail.billenius.com";
+    domains = [ "billenius.com" ];
+
+    x509.useACMEHost = config.mailserver.fqdn;
+
+    # A list of all login accounts. To create the password hashes, use
+    # nix-shell -p mkpasswd --run 'mkpasswd -s'
+    accounts = {
+      "love@billenius.com" = {
+        hashedPasswordFile = ./mail-password-hash/love@billenius.com;
+        aliases = [ "postmaster@billenius.com" ];
+      };
+    };
+  };
+}

hosts/hermes/roundcube.nix

@@ -0,0 +1,46 @@
+{
+  config,
+  pkgs,
+  ...
+}:
+{
+  services.roundcube = {
+    enable = true;
+    hostName = "mail.billenius.com";
+    package = pkgs.roundcube.withPlugins (
+      plugins: with plugins; [
+        persistent_login
+      ]
+    );
+    plugins = [
+      "persistent_login"
+      "managesieve" # built-in
+    ];
+    dicts = with pkgs.aspellDicts; [
+      # https://search.nixos.org/packages?query=aspellDicts
+      en 
+      sv
+    ];
+    maxAttachmentSize = config.mailserver.messageSizeLimit / 1024 / 1024;
+    extraConfig = ''
+      $config['imap_host'] = "ssl://${config.mailserver.fqdn}";
+      $config['smtp_host'] = "ssl://${config.mailserver.fqdn}";
+      $config['smtp_user'] = "%u";
+      $config['smtp_pass'] = "%p";
+
+      $config['managesieve_host'] = "tls://${config.mailserver.fqdn}";
+      $config['managesieve_port'] = 4190;
+      $config['managesieve_usetls'] = true;
+    '';
+  };
+
+  services.nginx.virtualHosts.${config.services.roundcube.hostName} = {
+    enableACME = true;
+    forceSSL = true;
+  };
+
+  networking.firewall.allowedTCPPorts = [
+    80
+    443
+  ];
+}